--.--.-- *--*
上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。

はじめてのAurigaスクリプト 基本編(16)

2011.05.14 *Sat*

//------------------------------
// アイテムの交換
//------------------------------

prontera.gat,154,184,4 script 福引券交換所 715,{

mes "[福引券交換員]";
mes "いらっしゃい!";
mes "ここは福引券の交換所だよ!";
mes "^0000FF福引き補助券^000000 5枚 で";
mes "福引き券 1枚 と交換するよ!";
next;

// 所持個数を調べる
set '@count, countitem(6301); // 6301#福引き補助券#

if ( '@count < 5 ){
mes "[福引券交換員]";
mes "福引き補助券が5枚以上";
mes "集まったらいつでもおいでよ!";
close;
}

mes "[福引券交換員]";
mes "おっ、集まってるね!";
mes "じゃ交換してあげよう。";
mes "交換方法を選んでね!";
next;

switch(
select(
"可能なだけ全部交換する",
"指定した数だけ交換する",
"キャンセル"
)
){
case 1: //全部////////////////////

set '@give, '@count / 5;
break;

case 2: //指定個数////////////////

mes "[福引券交換員]";
mes "いくつ欲しいんだい?";
mes "1未満でキャンセルだよ。";
next;

input '@give; //数値入力

if( '@give < 1 )
goto L_CANCEL;

if( '@give > '@count / 5 ){
mes "[福引券交換員]";
mes "あれれ?キミは";
mes "そんなに補助券を";
mes "もっていないようだよ。";
close;
}
break;

case 3: //キャンセル///////////////
goto L_CANCEL;
}

if( checkweight( 6300, '@give ) == 0){
mes "[福引券交換員]";
mes "あれれ?キミキミ。";
mes "アイテム持ちすぎなんじゃない?";
mes "重量だけじゃなくて";
mes "種類が多すぎても持てなくなる";
mes "から確認してごらんよ。";
close;
}

delitem 6301, '@give * 5; //6301#福引き補助券# 削除
getitem 6300, '@give; //6300#福引き券# 取得

mes "[福引所係員]";
mes "は~い。どうぞ!";
mes "福引き楽しんでね~。";
mes "幸運を祈ってるよ!";
close;

L_CANCEL: //キャンセル

mes "[福引所係員]";
mes "おや、やめるんだね?";
mes "交換したくなったら";
mes "またおいでよ!";
close;

}

/*-------------------------------
解説:

これはオリデオコン・エルニウムの
原石交換NPCなどと同じタイプで
Zenyで販売するのではなく、
決まった個数のアイテムを
別のアイテムへ交換するNPCです。

エル・オリ交換NPCと異なるのは
まとめて交換が行える点です。

基本的な仕組みは、今までのおさらいですね。

・countitem関数で、持っている数を調べ、
・checkweight関数で交換する個数が所持できるか確認、
・delitem関数で材料アイテムの削除。
・geiitem関数でアイテムを受け渡し。

あとはスクリプトをシンプルにする為に
数値入力時のキャンセルと、選択のキャンセルのメッセージを
ラベルを使用してメッセージを1箇所にまとめています。

goto L_CANCEL;

*/
関連記事

COMMENT

Comment Form


秘密にする
 


TRACKBACK

TrackBack List



プロフィール

Author:みのり

すごく面倒臭がりで大雑把です。
なので、すぐ楽をしようとして
ツールを作り始めます。
ツールを作る時間と手作業で費やす時間
はたしてどちらが短いのか……


-構築環境-

Auriga0945 MySQL 5.5
with 2011-12-20bRagexeRE

3CeAM rev525
with 2010-07-30aRagexeRE



カテゴリ

未分類 (9)
RagexeRE (9)
eAthena (1)
Auriga (5)
ツール:eAthena用 (4)
ツール:Auriga用 (6)
ツール:その他 (14)
はじめてのAurigaスクリプト (8)
はじめてのAurigaスクリプト基本編 (21)
はじめてのAurigaスクリプト応用編 (7)
Aurigaスクリプト (3)
本鯖 (7)
Aurigaスクリプト:冒険者アカデミー (6)
ドラクエ10 (2)
新生FF14 (3)
EVE Online (2)



最新記事



最新コメント



月別アーカイブ



検索フォーム



リンク

このブログをリンクに追加する



ブロとも申請フォーム

この人とブロともになる



QRコード

QR



12
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Copyright © Rocco di Forte All Rights Reserved.
テンプレート配布者: サリイ  ・・・  素材: HELIUM  ・・・ 
上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。